#-------------------------------------------------
#
# Project created by QtCreator 2012-08-15T03:35:56
#
#-------------------------------------------------


QT       += core gui

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets printsupport

win32 {
	greaterThan(QT_MAJOR_VERSION, 4) | greaterThan(QT_MINOR_VERSION, 7) :   LIBS += shell32.lib gdi32.lib user32.lib shlwapi.lib
}

win32 {
	lessThan(QT_MAJOR_VERSION, 5) {
    		lessThan(QT_MINOR_VERSION, 8): LIBS += -lshlwapi
	}
}

greaterThan(QT_MAJOR_VERSION, 4) {
    DEFINES += QT5
    lessThan(QT_MINOR_VERSION, 1): DEFINES += QT5_0
}

lessThan(QT_MAJOR_VERSION, 5) {
    greaterThan(QT_MINOR_VERSION, 7): DEFINES += QT4_8
    lessThan(QT_MINOR_VERSION, 8): DEFINES += QT4_7
}

DEFINES += _QT_PLATFORM_
DEFINES += _CRT_SECURE_NO_WARNINGS

TARGET = WinCaml
CONFIG   += console
CONFIG   -= app_bundle
CONFIG   += release
CONFIG   += static

unix {
	QMAKE_RPATHDIR += /$(QTDIR)/lib
}

TEMPLATE = app

ICON = ../sources/Qt/resources/WinCamlIcon.icns

SOURCES += \
    ../sources/All/Utils.cpp \
    ../sources/All/lex.zz.cpp \
    ../sources/All/lex.yy.cpp \
    ../sources/All/lex.tt.cpp \
    ../sources/All/CUndoManager.cpp \
    ../sources/All/CSplitter.cpp \
    ../sources/All/COutput.cpp \
	../sources/All/OCamlIndenter.cpp \
    ../sources/All/CInput.cpp \
    ../sources/All/CHighlighter.cpp \
    ../sources/All/CFrame.cpp \
    ../sources/All/CChildFrame.cpp \
	../sources/All/CamlIndenter.cpp \
	../sources/Qt/Qt.cpp \
	../sources/Qt/Paths.cpp \
    ../sources/All/main.cpp
    
HEADERS += \
    ../sources/All/Utils.h \
    ../sources/All/resource.h \
    ../sources/All/platform.h \
    ../sources/All/CUndoManager.h \
    ../sources/All/CSplitter.h \
    ../sources/All/COutput.h \
	../sources/All/OCamlIndenter.h \
    ../sources/All/CInput.h \
	../sources/All/HighlightLexer.h \
    ../sources/All/CHighlighter.h \
    ../sources/All/CFrame.h \
    ../sources/All/CChildFrame.h \
	../sources/All/CamlIndenter.h \
    ../sources/Qt/Qt.h

RESOURCES += \
    ../sources/Qt/resources/WinCaml.qrc

RC_FILE 	= ../sources/Qt/resources/WinCaml.rc
